Список установленных программ (VBS)

Обсуждение вопросов программирования (WSH/JScript/VBScript, CMD), проблемы и решения
Закрыто
nhutils
Сообщения: 595
Зарегистрирован: 09 дек 2009, 18:08
Контактная информация:

Список установленных программ (VBS)

Сообщение nhutils »

Скрипт позволяет получить список установленных программ локального компьютера или компьютера в сети (взят с Microsoft).
Может быть полезен системному администратору для контроля программ, установленных на компьютерах в сети.

Код: Выделить всё

Const HKLM = &H80000002 'HKEY_LOCAL_MACHINE
strComputer = "computer"
strKey = "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\"
strEntry1a = "DisplayName"
strEntry1b = "QuietDisplayName"
strEntry2 = "InstallDate"
strEntry3 = "VersionMajor"
strEntry4 = "VersionMinor"
strEntry5 = "EstimatedSize"

Set objReg = GetObject("winmgmts://" & strComputer & _
 "/root/default:StdRegProv")
objReg.EnumKey HKLM, strKey, arrSubkeys
WScript.Echo "Installed Applications (" & strComputer & ")" & VbCrLf
For Each strSubkey In arrSubkeys
  intRet1 = objReg.GetStringValue(HKLM, strKey & strSubkey, _
   strEntry1a, strValue1)
  If intRet1 <> 0 Then
    objReg.GetStringValue HKLM, strKey & strSubkey, _
     strEntry1b, strValue1
  End If
  If strValue1 <> "" Then
    WScript.Echo VbCrLf & "Display Name: " & strValue1
  End If
  objReg.GetStringValue HKLM, strKey & strSubkey, _
   strEntry2, strValue2
  If strValue2 <> "" Then
    WScript.Echo "Install Date: " & strValue2
  End If
  objReg.GetDWORDValue HKLM, strKey & strSubkey, _
   strEntry3, intValue3
  objReg.GetDWORDValue HKLM, strKey & strSubkey, _
   strEntry4, intValue4
  If intValue3 <> "" Then
     WScript.Echo "Version: " & intValue3 & "." & intValue4
  End If
  objReg.GetDWORDValue HKLM, strKey & strSubkey, _
   strEntry5, intValue5
  If intValue5 <> "" Then
    WScript.Echo "Estimated Size: " & Round(intValue5/1024, 3) & " megabytes"
  End If
Next
Скрипт подключается к компьютеру с сетевым именем, заданным переменной strComputer и просматривает раздел реестра SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\
Beliberdiev
Сообщения: 2
Зарегистрирован: 10 дек 2015, 20:29

Список установленных программ VBS

Сообщение Beliberdiev »

Собственно требуется получить список установленных в windows приложений и путей к ним, ничего на ум не приходит, при гуглении только ветка uinstall в реестре, там и терти нет установленных приложений... Может кто сталкивался, или есть идеи.
nhutils
Сообщения: 595
Зарегистрирован: 09 дек 2009, 18:08
Контактная информация:

Re: Список установленных программ (VBS)

Сообщение nhutils »

Список установленных программ учитывает программы «текущего пользователя», «всех пользователей», 32-хбитные программы в Windows x64, в итоге получается список всех программ.
Закрыто